B计划之移位

无心人

对这个专题 有些生疏了 先贴上很早以前的代码

1. //移位 假设es = ds
2. //左移 pL << s = pA (s < 32)
3. void AsmShl(unsigned long * pL, unsigned long * pA, unsigned long t, unsigned long s)
4. {
5. if (t == 0)
6. return;
7. asm {
8. push ds
9. mov ebx, t
10. mov ecx, s
11. lea esi, dword ptr pL
12. lea edi, dword ptr pA
13. mov edx, 0
14. cld
15. }
16. AsmShl1:
17. asm {
18. lodsd
19. push eax
20. shld eax, edx, cl
21. pop edx
22. stosd
23. dec ebx
24. jnz AsmShl1
25. mov bl, 32
26. sub bl, cl
27. mov cl, bl
28. shr edx, cl
29. mov [edi], edx
30. pop ds
31. }
32. }
34. //右移 pL >> s = pA (s < 32)
35. void AsmShr(unsigned long * pL, unsigned long * pA, unsigned long t, unsigned long s)
36. {
37. if (t == 0)
38. return;
39. asm {
40. push ds
41. mov ebx, t
42. mov ecx, s
43. lea esi, dword ptr pL
44. lea edi, dword ptr pA
45. mov edx, [esi]
46. add esi, 4
47. dec ebx
48. jz AsmShr2
49. cld
50. }
51. AsmShr1:
52. asm {
53. lodsd
54. shrd edx, eax, cl
55. xchg edx, eax
56. stosd
57. dec ebx
58. jnz AsmShr1
59. }
60. AsmShr2:
61. asm {
62. shr edx, cl
63. mov [edi], edx
64. pop ds
65. }
66. }

复制代码

然后考虑做出优化的代码来 可以用MMX/SSE/SSE2等指令

无心人

2. typedef unsigned int DWORD;
4. //左移 pL << s = pA (s < 32)
5. //最高位移出的数据做返回值
6. //不检查t, s为0的情况，乃高级函数的事情
7. __declspec(naked)
8. DWORD __cdecl BAsmShl(DWORD * pA, DWORD * pL, DWORD t, DWORD s)
9. {
11. __asm {
12. push ebx
13. push esi
14. push edi
15. mov ecx, [esp + 12 + 16]
16. mov ebx, [esp + 12 + 12]
17. shl ebx, 2
18. mov esi, [esp + 12 + 8]
19. add esi, ebx
20. mov edi, [esp + 12 + 4]
21. add edi, ebx
22. neg ebx
23. xor edx, edx
24. AsmShl1:
25. mov eax, dword ptr [esi + ebx]
26. shld eax, edx, cl
27. mov edx, dword ptr [esi + ebx]
28. mov dword ptr [edi + ebx], eax
29. add ebx, 4
30. jnz AsmShl1
31. sub ecx, 32
32. neg ecx
33. mov eax, edx
34. shr eax, cl
35. pop edi
36. pop esi
37. pop ebx
38. ret
39. }
40. }

复制代码

优化1， 通用版本

无心人

好了 2#的程序测试完成了 另外，ALU形式的不知道是否4路展开合适否 下一个考虑MMX形式的

无心人

1. __declspec(naked)
2. DWORD __cdecl BAsmShl_MMX(DWORD * pA, DWORD * pL, DWORD t, DWORD s)
3. {
5. __asm {
6. movd mm0, dword ptr [esp + 16] //s
7. mov ecx, dword ptr [esp + 12] //t
8. mov eax, dword ptr [esp + 8]
9. shl ecx, 2
10. add eax, ecx
11. mov edx, dword ptr [esp + 4]
12. add edx, ecx
13. neg ecx
14. pxor mm1, mm1
15. asmLoop1:
16. movd mm2, dword ptr [eax + ecx]
17. psllq mm2, mm0
18. por mm2, mm1
19. movd dword ptr [edx + ecx], mm2
20. punpckhdq mm2, mm1
21. movq mm1, mm2
22. add ecx, 4
23. jnz asmLoop1
24. movd eax, mm1
25. emms
26. ret
27. }
28. }

复制代码

时间几乎和ALU版本相同

无心人

Core 2 XEON 1.6G 100万次1024DWORD左移3位 两个版本都是1.95秒 差距在0.01秒以下 大概3.07Clock/DWORD