用vc2008开发64位程序，懂的请进

G-Spider

对于ml64.exe 均使用_fastcall方式，用masm64写独立汇编时还有其他很多不便之处，相比masm32。 Win64汇编语言与C语言混合编程 如果习惯了masm语法，个人推荐用JWasm。 1. JWasm is written in C ，开源。 2. C header files can be converted to include files ，所用头文件由sdk之类的c头文件所转，继承了c头文件多选择式定义的优点，比如32位64位头文件均可在一个文件中定义。 3. SSE4.2 are supported 4.precompiled JWasm binaries are available for DOS, Windows and Linux. For OS/2 and FreeBSD, makefiles are supplied. 多平台。 5.JWasm is faster than Masm. 6.JWasm is free, no artificial license restrictions, can be used to create binaries for any OS. 7.JWasm is a free MASM-compatible assembler . masm32编写的源文件可以不加修改的用JWasm编译。 汇编器JWASM.EXE 集成了16,32,64位的编译模式，masm高级语法被一致支持，比如.if .endif ，ml64.exe则不包含；调用规则也具多样性，不再是ml64.exe单纯的fastcall。 如果头文件定义的很好，写一个程序，加上不同的编译选择，就有可能生成32位，64位的可执行文件。 形如编译命令：

2. ;--- Win32/64 console application, uses WinInc v2+.
3. ;--- It can be used to generate both Win32 and Win64 binaries:
4. ;--- 32bit:
5. ;--- jwasm -coff -I\WinInc\Include WinXX_1.asm
6. ;--- link /subsystem:console /Libpath:\WinInc\Lib WinXX_1.obj
7. ;--- 64bit:
8. ;--- jwasm -win64 -Zp8 -I\WinInc\Include WinXX_1.asm
9. ;--- link /subsystem:console /Libpath:\WinInc\Lib64 WinXX_1.obj

复制代码

liangbch

我一直在思考一个问题，是否能在32位模式下使用64位寄存器和一些64位指令。比如，在32位模式下，计算2个__int64的整数的和很费时，不得不使用adc指令，而使用64为寄存器和64位算术指令可以很快算出结果。 我尝试使用JWasm编译一个汇编文件，不使用win64参数，但是Jwasm总报错。

liangbch

不是能否使用emit 绕开汇编器的限制。

gxqcn

我一直在思考一个问题，是否能在32位模式下使用64位寄存器和一些64位指令。比如，在32位模式下，计算2个__int64的整数的和很费时，不得不使用adc指令，而使用64为寄存器和64位算术指令可以很快算出结果。 我尝试使 ... liangbch 发表于 2011-4-21 21:12

也许可以尝试用 MMX 寄存器？（用 SSE2 指令 PADDQ）

liangbch

尝试使用 emit 绕开编译器限制，在32位模式下使用64bit 指令。 编译成功。运行也不出现异常，但是结果不对。不知是我的指令写的有问题，还是确实在32位模式下不能运行64位指令。

1. #include <stdlib.h>
2. #include <stdio.h>
4. void arrayAdd_c(__int64 *p1, __int64 *p2)
5. {
6. *p1 += *p2;
7. }
9. _declspec(naked)
10. void arrayAdd_asm( __int64 *p1, __int64 *p2)
11. {
12. __asm
13. {
14. push esi
15. push edi
17. mov edi, [esp+8+4]
18. mov esi, [esp+8+8]
20. mov eax,[edi]
21. mov edx,[edi+4]
22. add eax,[esi]
23. adc edx,[esi+4]
24. mov [edi],eax
25. mov [edi+4],edx
28. pop edi
29. pop esi
31. ret
32. }
33. }
35. _declspec(naked)
36. void arrayAdd_asm64( __int64 *p1, __int64 *p2)
37. {
38. __asm
39. {
40. push esi
41. push edi
43. mov edi, [esp+8+4]
44. mov esi, [esp+8+8]
47. //mov rax,qword ptr [edi]
48. __asm _emit 0x67
49. __asm _emit 0x48
50. __asm _emit 0x8B
51. __asm _emit 0x07
53. //mov rdx,qword ptr [esi]
54. __asm _emit 0x67
55. __asm _emit 0x48
56. __asm _emit 0x8B
57. __asm _emit 0x16
59. //add rax, rdx
60. __asm _emit 0x48
61. __asm _emit 0x03
62. __asm _emit 0xC2
64. //mov qword ptr [edi], rax
65. __asm _emit 0x67
66. __asm _emit 0x48
67. __asm _emit 0x89
68. __asm _emit 0x07
70. /*
71. movq mm0,qword ptr [edi]
72. movq mm1,qword ptr [esi]
73. paddq mm0, mm1
74. movq qword ptr [edi], mm0
75. */
77. pop edi
78. pop esi
80. ret
81. }
82. }
85. int main()
86. {
87. __int64 a1,a2,a3;
88. __int64 b1,b2,b3;
90. a1=a2=a3=12345678987654321I64;
91. b1=b2=b3=5000000000I64;
93. printf("a1=%I64d,a2=%I64d,a3=%I64d\n",a1,a2,a3);
95. arrayAdd_c(&a1,&b1);
96. arrayAdd_asm(&a2,&b2);
97. arrayAdd_asm64(&a3,&b3);
99. printf("a1=%I64d,a2=%I64d,a3=%I64d\n",a1,a2,a3);
101. }

复制代码

liangbch

贴出运行结果，可以看到a3的值不对，说明arrayAdd_asm64工作不正常。

1. a1=12345678987654321,a2=12345678987654321,a3=12345678987654321
2. a1=12345683987654321,a2=12345683987654321,a3=12345679692687022
3. 请按任意键继续. . .

复制代码

liangbch

在 函数 arrayAdd_asm64中，注释掉64位指令，改用MMX指令，发现结果是正确的。

G-Spider

15# liangbch 呵呵，想法很大胆，我想也有很多人想过。生成32可执行文件，至少PE格式已指明了32位，rax高位就对你透明了。如果32位中用部分64寄存器和指令，我猜要切换模式，可能会有一些特权指令，ring3下也用不了，可什么时候切换呢？暂时没找到这样的例子，只好想象一下32位与64位的程序在时间片轮转中的情形。 以上都是个人猜测。

G-Spider

JWasm的16/32/64是集成的,考虑到MS 的ml.exe 和ml64.exe 仍然可统一win32/win64编程. 调用规则上,win32多样,而win64只有fastcall (JWasm也如此)。所以为了调用的外观上一致,写了一个调用宏_invoke ,解决了这个问题。在编译和链接的时候,它们各自调用自己的include 和lib文件,源代码是共用的,干净凝练。 相关说明在代码中。 src.rar (3.27 KB, 下载次数: 1)

2011-4-27 15:12 上传

点击文件名下载附件

1. ;---------------------------------------------------------------
2. ;---------------------------------------------------------------
3. ;--- Win32/Win64 simple GUI application. By G-Spider 2011
4. ;--- Note: requires ml.exe \ml64.exe ,link.exe
5. ;---------------------------------------------------------------
6. ;--- X86
7. ;--- ml /c /coff file.ASM
8. ;--- link /out:win32.exe /subsystem:windows /entry:main file.obj
9. ;---------------------------------------------------------------
10. ;--- X64
11. ;--- ml64 /c /Zp8 /D _WIN64=1 file.ASM
12. ;--- link /out:win64.exe /subsystem:windows /entry:main file.obj
13. ;---------------------------------------------------------------
14. ;---------------------------------------------------------------
15. ;说明:ml.exe 和ml64.exe中有个命令选项:
16. ;/D sysmbol=value 定义给定名字的文本宏。
17. ;所以可以通过这个命令来自动选择源代码中的x86或x64部分.
18. ;在x86中,默认不用设置/D sysmbol=value或设置/D _WIN64=0
19. ;若选择ml64.exe编译,可以加上/D _WIN64=1即可
20. ;/Zp[n] 对结构指定的字节边界对齐
21. ;---------------------------------------------------------------
23. ifndef _WIN64
24. _WIN64 equ <0>
25. endif
28. if _WIN64 eq 0 ;no -_WIN64 switch?
29. .386
30. .model flat, stdcall
31. rax equ <eax>
32. rbx equ <ebx>
33. rcx equ <ecx>
34. rdx equ <edx>
35. rsp equ <esp>
36. rbp equ <ebp>
37. rsi equ <esi>
38. rdi equ <edi>
39. ;//如果x64的inc文件也合法的话,可以通用include ,只是路径不一样
40. ;//一个是masm32\include 一个是masm64\include
41. include user32.inc
42. include kernel32.inc
44. else ;_WIN64不为0 开启64位
45. ;//X64的inc文件可以写成如下形式
46. ;//用晓风残月的生成def/inc64工具即可
47. extrn wsprintfA : proc
48. extrn MessageBoxA : proc
49. extrn ExitProcess : proc
50. ;//
51. endif
53. option casemap:none
55. includelib kernel32.lib
56. includelib user32.lib
57. ;================================================
58. ;以下为通用调用宏
59. ;================================================
60. ;------------------------------------------------
61. ; 参数翻转
62. ;------------------------------------------------
63. reverseArgs macro arglist:VARARG
64. local txt,count
66. txt TEXTEQU <>
67. count = 0
68. for i, <arglist>
69. count=count+1
70. txt TEXTEQU @CatStr(i, <,> , <%txt> )
71. endm
72. if count GT 0
73. txt SUBSTR txt,1,@SizeStr(%txt)-1
74. endif
75. exitm txt
76. endm
78. ;------------------------------------------------
79. ; 一个x86\x64 invoke Macro
80. ;------------------------------------------------
81. _invoke macro _Proc,args:VARARG
82. local count
83. local stack
84. local rspL
86. count= 0
87. if _WIN64 NE 0 ;//不等于0时,选择X64,fastcall
88. rspL = 20h
89. % for i,<args>
90. count=count+1
91. if count GT 4
92. rspL= rspL + 8h
93. endif
94. endm
95. count=rspL/16
96. count=count*16
97. if rspL EQ count
98. rspL=rspL+8
99. endif
101. sub rsp,rspL
103. count = 0
104. stack = 0
105. % for i,<args>
106. count = count + 1
107. if count EQ 1
108. mov rcx,i
109. elseif count EQ 2
110. mov rdx,i
111. elseif count EQ 3
112. mov r8,i
113. elseif count EQ 4
114. mov r9,i
115. elseif count GE 5
116. mov rax,i
117. mov qword ptr [rsp+stack],rax
118. endif
119. stack = stack + 8
120. endm
121. call [_Proc]
122. add rsp,rspL
123. else
124. % for i,< reverseArgs( args ) >
125. count = count + 1
126. push i
127. endm
128. call [_Proc]
129. endif
131. endm
132. ;================================================
133. ;以上为通用调用宏
134. ;================================================
136. .data
137. imsg byte 'this invoke feels like 32bit',0
138. szFmt1 byte '%d',0
139. szFmt2 byte '%d %d',0
140. szFmt3 byte '%d %d %d',0
141. szFmt4 byte '%d %d %d %d ',0
142. .data?
143. Buffer dword 8 dup(?)
145. .code
146. main proc
147. ;========================
148. _invoke wsprintfA,offset Buffer,offset szFmt1,10h
149. _invoke wsprintfA,offset Buffer,offset szFmt2,10h,16h
150. _invoke wsprintfA,offset Buffer,offset szFmt3,10h,16h,17h
151. _invoke wsprintfA,offset Buffer,offset szFmt4,10h,16h,17h,18h
153. ;========================
154. _invoke MessageBoxA,0,offset imsg,offset Buffer,0
155. _invoke ExitProcess,0
157. main endp
158. end

复制代码

gxqcn

我只进行过嵌入式汇编，对楼上的独立的asm文件操作不熟悉。 据说64位下VC不支持内嵌汇编（消息可靠否），不知Intel的编译器是否还支持？