如何求出这个三元方程组的数值解？

王守恩

nyy 发表于 2023-8-15 18:27
@王守恩 又没有任何有效的回答，你激动个啥？
不知道是不是本论坛的人提的问题。

1. area[R_, a_, b_] :=Module[{n, m, out}, n=(b - a - Sin[(b - a)])R^2/2; m=Abs[(Cos[b] - Cos[a]) (Sin[b] - Sin[a])]R^2/2; out = n + m]
   
2. ans = FindRoot[{area[R, a, b] ==12, area[R, Pi- a, 2 Pi- b] == 20, area[R, 2 Pi - b, 2 Pi+ a] ==25}, {{R, 4}, {a, 10/60}, {b, 80/60}}]
   
3. S = Pi R^2 - area[R, a, b] - area[R, Pi - a, 2 Pi - b] - area[R, 2 Pi - b, 2 Pi + a] /. ans
   
4. Solve[{Pi*R^2/2==S+12+(a+Sin[2a]/2)R^2==20+25-(a+Sin[2a]/2)R^2==12+20+(b+Sin[2b]/2)R^2==25+S-(b+Sin[2b]/2)R^2,R>0,S>0,30/60>a>0,30/60>b>0},{a,b,R,S}]

复制代码

求助:我就是不知道怎么把(4)装进(1)(2)(3)去。
或3)装进(2)?(1)装进(2)?
太难了，登天还难。

Jack315

31.6762 的图是这个样子的：



圆半径为 r=5.1609。
P 点坐标为 x=0.9587 和 y=-0.9587
位于 135 度线上。

（下面这个图删不掉了 ）

wayne

..
借用24#的图. 直接面积加减法.

$S_1 = S_{扇形OCD} - S_{三角形OPD} - S_{三角形OPC}$
$S_2 = S_{扇形OBC} + S_{三角形OPC} - S_{三角形OPB}$
$S_3 = S_{扇形OAB} + S_{三角形OPA} + S_{三角形OPB}$
$S_4 = S_{扇形OAD} + S_{三角形OPD} - S_{三角形OPA}$

设$OP=d,  u = d \cos (\alpha ) = R \cos (x)$, $v =d \sin (\alpha ) = R \cos (y)$, 列出表达式为
$-\frac{1}{2} d R \sin (x-\alpha )+\frac{1}{2} d R \cos (\alpha +y)+\frac{1}{2} R^2 \left(x+y-\frac{\pi }{2}\right)=12$
$-\frac{1}{2} d R \sin (\alpha +x)-\frac{1}{2} d R \cos (\alpha +y)+\frac{1}{2} R^2 \left(x-y+\frac{\pi }{2}\right)=20$
$\frac{1}{2} d R \sin (\alpha +x)+\frac{1}{2} d R \cos (y-\alpha )+\frac{1}{2} R^2 \left(-x-y+\frac{3 \pi }{2}\right)=25$
$\frac{1}{2} d R \sin (x-\alpha )-\frac{1}{2} d R \cos (y-\alpha )+\frac{1}{2} R^2 \left(-x+y+\frac{\pi }{2}\right)=S$
代入 $d \cos (\alpha ) \to R \cos (x)$, $d \sin (\alpha ) \to R \cos (y)$ ,得到
$R^2[ (-\pi/4 + (x + y)/2) - (Sin[2 x] + Sin[2 y])/4 + Cos[x] Cos[y]] = 12$,
$R^2[(\pi/4 + (x - y)/2) - (Sin[2 x] - Sin[2 y])/4 - Cos[x] Cos[y] ]= 20$
$R^2[ (\frac{3\pi}{4} - (x + y)/2) + (Sin[2 x] + Sin[2 y])/4 + Cos[x] Cos[y] ]= 25$
$R^2[ (\pi/4 - (x - y)/2) + (Sin[2 x] - Sin[2 y])/4 - Cos[x] Cos[y]] = S$

1. sol=TrigExpand[{1/2R^2(x+y-Pi/2)-1/2R d Sin[x-\[Alpha]]-1/2R d Sin[y-(Pi/2-\[Alpha])]==12,
   
2. 1/2R^2(x-y+Pi/2)-1/2R d Sin[x+\[Alpha]]+1/2R d Sin[y-(Pi/2-\[Alpha])]==20,
   
3. 1/2R^2(2Pi-(x+y+Pi/2))+1/2R d Sin[x+\[Alpha]]+1/2R d Sin[y+(Pi/2-\[Alpha])]==25,
   
4. 1/2R^2(y-x+Pi/2)+1/2R d Sin[x-\[Alpha]]-1/2R d Sin[y+(Pi/2-\[Alpha])]==S}]/.{d  Cos[\[Alpha]]->R Cos[x],d  Sin[\[Alpha]]->R Cos[y]}
   
5. Eliminate[sol,{R,S}]

复制代码

跟7# 和9# 的结构 都比较类似.
\[\left\{ \begin{array}{l}
64 \cos (x) \cos (y)-37 x+37 \sin (x) \cos (x)+16 \pi =0 \\
180 \cos (x) \cos (y)+74 y-74 \sin (y) \cos (y)-29 \pi =0 \\
S = \frac{17 \pi -228 \cos (x) \cos (y)}{4 \cos (x) \cos (y)+\pi } \\
\end{array} \right.\]
数值解就是

1. FindRoot[sol, {{x, 1}, {y, 1}, {R, 1}, {S, 1}},  WorkingPrecision -> 100]

复制代码

1. {x->1.479562523482503437776738698107319809676480650279014451160437712048379185605335033904215447591948991,
   
2. y->1.377272602814462853186131203706929797854803642104178086827821236519830595354315839796202069063838094,
   
3. R->4.800094607277248765851985987118642066763331826398128627436431334969912416189838911534091245956958841,
   
4. S->15.38514805508871342500004107511989278433570526627393947940780984580291479054228346327225883902552547}

复制代码

画图就是

再给一个全局图

Jack315

wayne 发表于 2023-8-16 07:07
..

这个计算方法应该是比较简洁的一种。
只是在计算角度时，如果 P 点在不同象限，
公式在形式上可能会有差别。
如果用公式能得到六个解，就没有问题。
否则可能就是上面说的这个问题。

另外，能比较详细地讲解下这个帖子 [原创] 求红色线段的长度值 中 8#
关于无穷级数求和的方法吗？说明一下利用留数定理的具体思路也行。
我估计自己就卡在哪个关键点上，还望大佬点拨一下

wayne

再笼统的给一个一般化的方程, 除了第一个方程,每个方程的几何意义都很明显,谁能解释一下第一个方程的几何意义?
$\cos (x) \cos (y)=\frac{\pi  (-S+\text{S1}-\text{S2}+\text{S3})}{4 (S+\text{S1}+\text{S2}+\text{S3})},2 x-\sin (2 x)=\frac{2 \pi  (\text{S1}+\text{S2})}{S+\text{S1}+\text{S2}+\text{S3}} , 2 y-\sin (2 y)=\frac{2 \pi  (S+\text{S1})}{S+\text{S1}+\text{S2}+\text{S3}},\pi R^2=S+\text{S1}+\text{S2}+\text{S3}$

1. Block[{S1 = 12, S2 = 20, S3 = 25},
   
2. FindRoot[{Cos[x] Cos[y] == (\[Pi] (-S + S1 - S2 + S3))/(4 (S + S1 + S2 + S3)), (2 \[Pi] (S1 + S2))/(S + S1 + S2 + S3) + Sin[2 x] ==  2 x,
   
3. (2 \[Pi] (S + S1))/(S + S1 + S2 + S3) + Sin[2 y] == 2 y, \[Pi] R^2 == S + S1 + S2 + S3}, {{x, 1}, {y, 1}, {S, S1}, {R, 10}}, WorkingPrecision -> 100]]

复制代码

1. {x->1.479562523482503437776738698107319809676480650279014451160437712048379185605335033904215447591948991,
   
2. y->1.377272602814462853186131203706929797854803642104178086827821236519830595354315839796202069063838094,
   
3. S->15.38514805508871342500004107511989278433570526627393947940780984580291479054228346327225883902552547,
   
4. R->4.800094607277248765851985987118642066763331826398128627436431334969912416189838911534091245956958841}

复制代码

王守恩

1. Block[{S1=20,S2=12,S3=25},FindRoot[{2(S1+S2)/(2a-Sin[2a])==2(S1+S)/(2b-Sin[2b])==(S1-S2+S3-S)/(4Cos[a]Cos[b])==Pi*R^4/(S1+S2+S3+S)==R^2},{{R,4},{S,S1},{a,1},{b,1}},WorkingPrecision->9]]
   
2. Block[{S1=25,S2=12,S3=20},FindRoot[{2(S1+S2)/(2a-Sin[2a])==2(S1+S)/(2b-Sin[2b])==(S1-S2+S3-S)/(4Cos[a]Cos[b])==Pi*R^4/(S1+S2+S3+S)==R^2},{{R,4},{S,S1},{a,1},{b,1}},WorkingPrecision->9]]
   
3. Block[{S1=12,S2=20,S3=25},FindRoot[{2(S1+S2)/(2a-Sin[2a])==2(S1+S)/(2b-Sin[2b])==(S1-S2+S3-S)/(4Cos[a]Cos[b])==Pi*R^4/(S1+S2+S3+S)==R^2},{{R,4},{S,S1},{a,1},{b,1}},WorkingPrecision->9]]
   
4. Block[{S1=25,S2=20,S3=12},FindRoot[{2(S1+S2)/(2a-Sin[2a])==2(S1+S)/(2b-Sin[2b])==(S1-S2+S3-S)/(4Cos[a]Cos[b])==Pi*R^4/(S1+S2+S3+S)==R^2},{{R,4},{S,S1},{a,1},{b,1}},WorkingPrecision->9]]
   
5. Block[{S1=12,S2=25,S3=20},FindRoot[{2(S1+S2)/(2a-Sin[2a])==2(S1+S)/(2b-Sin[2b])==(S1-S2+S3-S)/(4Cos[a]Cos[b])==Pi*R^4/(S1+S2+S3+S)==R^2},{{R,4},{S,S1},{a,2},{b,1}},WorkingPrecision->9]]
   
6. Block[{S1=20,S2=25,S3=12},FindRoot[{2(S1+S2)/(2a-Sin[2a])==2(S1+S)/(2b-Sin[2b])==(S1-S2+S3-S)/(4Cos[a]Cos[b])==Pi*R^4/(S1+S2+S3+S)==R^2},{{R,4},{S,S1},{a,2},{b,1}},WorkingPrecision->9]]

复制代码

{R -> 5.52129591, 12. -> 38.7705363, a -> 1.30401157, b -> 1.75127984}
{R -> 5.52129591, 12. -> 38.7705364, a -> 1.39031282, b -> 1.83758109}
{R -> 4.80009461, 12. -> 15.3851481, a -> 1.47956252, b -> 1.37727260}
{R -> 4.80009461, 12. -> 15.3851481, a -> 1.76432005, b -> 1.66203013}
{R -> 4.59133032, 12. -> 9.22576002, a -> 1.66325722, b -> 1.28085908}
{R -> 4.59133032, 12. -> 9.22576008, a -> 1.86073357, b -> 1.47833543}

\(\D\frac{2 (S1 + S2)}{(2 a - \sin(2 a)) R^2}=\frac{ 2 (S1 + S)}{(2 b - \sin(2 b)) R^2}=\frac{ S1 - S2 + S3 - S}{4 \cos(a) \cos(b) R^2} =\frac{\pi*R^2}{S1 + S2 + S3 + S}=1\)

王守恩

对不起！浪费大家的时间，我还是说几句(不是小结)。

1圆被两条相互垂直直线分为4部分, 3部分的面积是12,20,25, 求剩下部分的面积。

往大的想，4部分有4种可能：
1，4部分是相同的。可以有唯一解。
2，3部分是相同的，无解。
3，2部分相同，另2部分相同。无解。
     2部分相同，另2部分不同，？？？
4，4部分都不相同，6个图形(3个R)。

4部分为S1,S2,S3,S4, 且S1≥S2≥S3≥S4,则S2*S3≥S1*S4
圆心肯定在S1。

重点：2部分相同，另2部分不同，？？？

2部分相同(肯定是对边)，另2部分不同(对边)，
4部分只能是S1≥S2≥S2≥S4,     ？(怎么确定)≥S2*S2≥S1*S4

譬如：12,20,20,25没有解？？？
12,20,20,31.6762可以有解。

nyy

王守恩 发表于 2023-8-16 16:22
{R -> 5.52129591, 12. -> 38.7705363, a -> 1.30401157, b -> 1.75127984}
{R -> 5.52129591, 12. -> 3 ...

你这个求面积不需要加绝对值吗？
他是用了格林公式？

王守恩

这个还是可以塞进去的。23#41#还是塞不进去。

1. FindRoot[{(2*S - a*b)/(2 x - Sin[2 x]) == (2*12 - a*c)/(2 y - Sin[2 y]) == (2*20 - c*d)/(\[Pi] - 2 x - Sin[2 x]) == (2*25 - b*d)/(\[Pi] - 2 y - Sin[2 y]) == R^2,
   
2. Sqrt[a^2 + b^2]/Sin[x] == Sqrt[a^2 + c^2]/Sin[y] == (b + c)/Sin[x + y] == 2 R,  a*d == b*c}, {{S, 1}, {R, 1}, {x, 1}, {y, 1}, {a, 1}, {b, 1}, {c, 1}, {d, 1}}, WorkingPrecision -> 9]

复制代码

{S -> 15.3851481, R -> 4.80009461, x -> 0.734253203, y -> 0.643019400, a -> 3.85698669, b -> 5.14781319, c -> 4.27316596, d -> 5.70327613}

Jack315

【分享成果】
计算四部分面积采用的方法为：
每一部分的面积=扇形面积-扇形内三角形的面积+直角三角形面积

在 Excel 和 Mathematica 中， ArcTan[x,y] 函数返回值范围为 \(-\pi<\alpha\le\pi\) 。
这导致圆心角的计算需要进行调整，相应的公式如下：
\[∠AOB=tan^{-1}\bigg(x_p,-\sqrt{r^2-x_p^2}\bigg)-tan^{-1}\bigg(-\sqrt{r^2-y_p^2},y_p\bigg)+\begin{cases} 0 & \text{if }y_p<0 \\ 2\pi & \text{if }y_p\ge0\end{cases}\]
\[∠BOC=tan^{-1}\bigg(\sqrt{r^2-y_p^2},y_p\bigg)-tan^{-1}\bigg(x_p,-\sqrt{r^2-x_p^2}\bigg)\]
\[∠COD=tan^{-1}\bigg(x_p,\sqrt{r^2-x_p^2}\bigg)-tan^{-1}\bigg(\sqrt{r^2-y_p^2},y_p\bigg)\]
\[∠DOA=tan^{-1}\bigg(-\sqrt{r^2-y_p^2},y_p\bigg)-tan^{-1}\bigg(x_p,\sqrt{r^2-x_p^2}\bigg)+\begin{cases} 2\pi & \text{if }y_p<0 \\ 0 & \text{if }y_p\ge0\end{cases}\]
由于对顶圆心角互补，即 \(∠AOB+∠COD=\pi\) 和 \(∠BOC+∠DOA=\pi\)，
所以只求 \(∠BOC\) 和 \(∠COD\)，另外两个角利用互补关系求出，相对地简化了计算公式。

下列附件中包含有 Excel 和 Mathematica 的工作文档：
圆内面积分割.part1.rar (250 KB, 下载次数: 2)

2023-8-19 08:53 上传

点击文件名下载附件

圆内面积分割.part2.rar (250 KB, 下载次数: 2)

2023-8-19 08:53 上传

点击文件名下载附件

（压缩文件有三个，上传受限了，最后一个明天补上）

Excel 文档可读性比较差；Mathematica 就好多了。
在 Excel 文档中，每个工作表最下面有简短的说明。
在 Mathematica 文档中定义了求面积的公式：

1. 计算四部分面积[半径_, x值_, y值_] :=
   
2. Module[{r = 半径, x = x值, y = y值, 临时长度, 分割线长度, 临时角度, 临时圆心角, 圆心角补角, 圆心角,
   
3.     扇形面积, 扇形内三角形面积, 直角三角形面积},
   
4.   
   
5.   (*=======================================================*)
   
6.   (* 计算各段分割线的长度                                        *)
   
7.   (*=======================================================*)
   
8.   (*第一个值为Sqrt[r^2-x^2]，垂直分割线长度的一半*)
   
9.   (*第二个值为Sqrt[r^2-y^2]，水平分割线长度的一半。*)
   
10.   临时长度 = Sqrt[r^2 - {x, y}^2];
    
11.   
    
12.   (*\[OpenCurlyDoubleQuote]分割线长度\[CloseCurlyDoubleQuote]\
    
13. 四个值为四段分割线的长度，依次为 PA、PB、PC 和 PD 的长度。*)
    
14.   分割线长度 = {x + 临时长度[[2]], y + 临时长度[[1]], 临时长度[[2]] - x, 临时长度[[1]] - y};
    
15.   
    
16.   (*=======================================================*)
    
17.   (*计算圆心角。                                                  *)
    
18.   (*=======================================================*)
    
19.   (*三个值依次为tan^-1(Sqrt[r^2-y^2],y)、tan^-1(x,-Sqrt[r^2-x^2])和tan^-1(x,
    
20.   Sqrt[r^2-x^2])，是与分割线与圆交点相关的极角，用于计算圆心角的中间临时变量。*)
    
21.   临时角度 = ArcTan[{临时长度[[2]], x, x}, {y, -临时长度[[1]], 临时长度[[1]]}];
    
22.   
    
23.   (*两个值依次为圆心角\[Angle]BOC和\[Angle]COD的角度。*)
    
24.   临时圆心角 = {临时角度[[1]] - 临时角度[[2]], 临时角度[[3]] - 临时角度[[1]]};
    
25.   
    
26.   (*两个值依次为圆心角\[Angle]DOA和\[Angle]AOB的角度。*)
    
27.   (*说明：对顶圆心角互补。*)
    
28.   圆心角补角 = \[Pi] - 临时圆心角;
    
29.   
    
30.   (*重新构造圆心角列表。*)
    
31.   (*四个值依次为圆心角\[Angle]AOB、\[Angle]BOC、\[Angle]COD和\[Angle]DOA的角度。*)
    
32.   圆心角 = {圆心角补角[[2]], 临时圆心角[[1]], 临时圆心角[[2]], 圆心角补角[[1]]};
    
33.   
    
34.   (*=======================================================*)
    
35.   (*计算面积。                                                    *)
    
36.   (*=======================================================*)
    
37.   (*四个值依次为扇形AOB、BOC、COD和DOA的面积。*)
    
38.   扇形面积 = r^2/2 圆心角;
    
39.   
    
40.   (*四个值依次为扇形内三角形\[EmptyUpTriangle]AOB、\[EmptyUpTriangle]BOC、\
    
41. \[EmptyUpTriangle]COD和\[EmptyUpTriangle]DOA的面积。*)
    
42.   扇形内三角形面积 = r^2/2 Sin[圆心角];
    
43.   
    
44.   (*四个值依次为直角三角形\[EmptyUpTriangle]APB、\[EmptyUpTriangle]BPC、\
    
45. \[EmptyUpTriangle]CPD和\[EmptyUpTriangle]DPA的面积。*)
    
46.   直角三角形面积 =
    
47.    1/2 Table[分割线长度[[i]]*分割线长度[[If[i < 4, i + 1, 1]]], {i, 1, 4}];
    
48.   (*=======================================================*)
    
49.   (*计算并返回四部分面积。                                       *)
    
50.   (*=======================================================*)
    
51.   (*四个值依次为 APB, BPC,CPD 和 DPA 的面积。*)
    
52.   扇形面积 - 扇形内三角形面积 + 直角三角形面积
    
53.   ]

复制代码

使用了三个不同的命令求解：Solve/NSolve、FindRoot 和 NMinimize 。
Solve/NSolve 命令求解失败；
运行效果 FindRoot 效果要好一些，数字精度高、速度也相对快一点。
最后画出了解的图形。